Subsections

1.4 トランスのSPICEモデル(シングル用)

SPICEでは,2つのインダクタとそれらの結合係数を指定した結合インダクタを使ってトランスを表します. 結合インダクタには,漏洩インダクタンスが存在しますが, 巻線抵抗および浮遊容量は存在しません. したがって,現実のトランスをシミュレートするには, 巻線抵抗と浮遊容量を結合インダクタに付け加える必要があります. SPICEでトランスをシミュレートする回路の例を, 図1.13に示します.
図 1.13: SPICEによるトランスのシミュレート(シングル用)
\begin{figure}\input{figs/opts_spice}
\end{figure}

巻線抵抗は,一次側,二次側を独立に測定できるので, そのまま付加します. 二次側の浮遊容量は,非常に小さいので,省略しても構わないでしょう. 一次側のインダクタのインダクタンスとしては,一次インダクタンス LP をそのまま使います. 二次側のインダクタのインダクタンスとしては,一次インダクタンスを巻数比の2乗で割ったもの(LP/n2 )を使います.

漏洩インダクタンス Ll と一次インダクタンス LP と結合係数 K の間には, 次のような関係があります.

K = $\displaystyle \sqrt{{1 - \frac{L_l}{L_P}}}$ (1.52)
一次インダクタンスが一次漏洩インダクタンスの何倍あるかを Q で表します. すなわち,
Q = $\displaystyle {\frac{{L_P}}{{L_{l1}}}}$ (1.53)
K $\displaystyle \approx$ 1 - $\displaystyle {\frac{{1}}{{Q}}}$ (1.54)
Q $\displaystyle \approx$ $\displaystyle {\frac{{1}}{{1-K}}}$ (1.55)

の関係があります. 出力トランスの場合,Q はだいたい1000程度ですから, 結合係数は K = 0.999 程度になります.

1.3.5節のパラメータを用いて作成したトランスのサブ回路は, 次のようになります.

1.4.0.0.1 OPT2k5.inc

    1 *
    2 *   OPT 2k5
    3 *
    4 .SUBCKT OPT2k5 P B S1 S0
    5 * Primary inductance (2500ohm 12.12H)
    6 L1 P 1 12.12
    7 * Iron loss
    8 RI P 1 291k
    9 * Primary DC resistance
   10 R1 1 B 146.8
   11 * Primary stray capacitance
   12 CP P B 393.3p
   13 * Secondary inductance (8ohm)
   14 L2 S1 2 0.04338939
   15 * Secondary DC resistance
   16 R2 2 S0 0.66
   17 * Secondary stray capacitance
   18 CS S1 S0 2840p
   19 * coupling factor
   20 K L1 L2 0.99959
   21 .ENDS

ayumi
2016-03-07